Results of my "photo to cartoon" plugin

cli345 · **Posted:** Tue Jun 08, 2021 1:05 pm **(#71)**

Hello,

Thanks, rich2005, mahvin, Krikor, Nidhogg, Issabella, level_0, MareroQ for your very valuable feedbacks! :tyspin

(particularly to MareroQ for the fix).

cli345 · **Posted:** Tue Jul 20, 2021 8:54 am **(#72)**

Hello!

Here is a similar filter (photo to cartoon). It's not exactly the same effect.

Attachment:

apples_k7252-65_compGegl.jpg [ 389.26 KiB | Viewed 9454 times ]

It's not better but it's made entirely with "GEGL graph".

Enjoy!

cli345 · **Posted:** Sun Jul 25, 2021 9:21 am **(#73)**

Hello!

It's just the "photo to cartoon" plugin ("Comic Book for 2.10") with an additional option: "Simplify".

If the "Simplify" option is 0, the plugin acts almost exactly according to the old behavior. If it's 1, a slight simplification is applied. For 2, a stronger one is applied.

Attachment:

small_farm_k7862-1_versions.jpg [ 330.06 KiB | Viewed 8808 times ]

EDIT: The new version appears as "Filters -> Artistic -> Simple Cartoon..."
Enjoy!

cli345 · **Posted:** Tue Jul 27, 2021 9:35 am **(#74)**

Hello!

Here is a very similar plugin written entirely in G'MIC.

Code: Select all

#@gui ____<b>Testing</b>
#@gui <i>cli345</i>
#------------------
#@gui Comic book: comic, comic_preview(0)
#@gui : note = note("<b>Note</b>: Photo to cartoon")
#@gui : sep = separator()
#@gui : note = note(" ")
#@gui : Simplification = choice(0, "none", "light", "light antialias", "strong antialias", "median", "iuwt", "thin brush")
#@gui : sep = separator()
#@gui : Flattening for edge (bilateral) = int(2,0,5)
#@gui : Edge method = choice(0, "Diff. of Gauss.", "Diff. of BoxBlur", "Diff. of Median")
#@gui : Edge desaturation method = choice(1, "Lightness", "MaxRGB", "MinRGB")
#@gui : Line thickness = float(1,0.5,2)
#@gui : Line strength = float(15,0,19)
#@gui : sep = separator()
#@gui : Add colors = bool(1)
#@gui : Luminosity increase = int(10,0,50)
#@gui : Saturation increase = int(20,0,50)
#@gui : sep = separator()
#@gui : Final flattening (bilateral) = int(6,0,10)
#@gui : Lines antialias = int(15,0,100)
#@gui : sep = separator()
#@gui : Colors to black or white = bool(0)

comic :
   simplif=$1
   nbBilatBord=$2
   methBord=$3
   methDesat=$4
   lineThick=$5
   forceTrait=$6
   addColors=$7
   augmLum=$8
   augmSat=$9
   nbBilatFin=$10
   antialias=$11
   bw=$12
   
   if $simplif==2
      fx_smooth_antialias. 100,0,2.5,0,50,50
   elif $simplif==3
      fx_smooth_antialias. 100,0,5,0,50,50
   elif $simplif==4
      fx_smooth_median. 3,255,0,0,50,50
   elif $simplif==5
      jeje_denoise_iuwt. 3,4,2,0
      jeje_denoise_iuwt. 3,4,2,0
   elif $simplif==6
      fx_smooth_anisotropic. 60,0.9,0.64,3.1,1.1,0.8,30,2,0,1,1,0,0,24
   fi
   
   +fx_curves_interactive.  7,0,1,7,0,0,{50-$augmLum},{50+$augmLum},100,100,-1,0,0,{50-$augmSat},{50+$augmSat},100,100,-1,0,0,100,100,-1,0,0,100,100,-1,
   fx_smooth_nlmeans.. 4,4,10,5,0,0,24,0
   fx_smooth_bilateral.. 10,7,$nbBilatBord,0,0
   
   +cut.. 0,255
   reverse[-2,-1]
   if $methBord==0
      blur[-3] {$lineThick}
   elif $methBord==1
      boxfilter[-3] xy,{$lineThick+0.01}
   elif $methBord==2
      median[-3] {($lineThick+0.01)*2}
   fi
   sub[-3,-2]
   
   if $methDesat==0
      fill.. "m = min(R,G,B); M = max(R,G,B); L = 0.5*(m + M); [L, L, L]"
   elif $methDesat==1
      fill.. "M = max(R,G,B); [M, M, M]"
   elif $methDesat==2
      fill.. "M = min(R,G,B); [M, M, M]"
   fi

   cut.. 0,255 n.. 0,255
   negate..
   threshold.. {$forceTrait+80}%
   n.. 0,255
   
   if $simplif>0
      fx_smooth_antialias.. 100,0,2.5,0,50,50
      fx_curves_interactive.. 7,0,1,7,0,0,69,0,70,100,100,100,-1,0,0,100,0,-1,0,0,100,100,-1,0,0,100,100,-1,
   fi
   
   fx_smooth_antialias.. $antialias,0,1,0,50,50
   
   if $addColors==1
      mul[-2,-1]
      n. 0,255
      fx_smooth_bilateral. 10,7,$nbBilatFin,0,0
      if $bw==1
         fx_curves_interactive 7,0,1,7,0,0,16,100,100,100,-1,0,0,100,0,-1,0,0,100,100,-1,0,0,100,100,-1,
      fi
   else
      remove[-1]
   fi

comic_preview :
   comic $*

Installation:

Copy the above code into a file "~/.gmic" on Linux or a file "%APPDATA%\gmic""%APPDATA%\user.gmic" on Windows.
The "plug-in" appears in "Filters -> G'MIC-Qt -> Testing -> cli345 -> Comic Book".

Here is a comparison with "Comic Book for 2.10":

Attachment:

apples_k7252-65_compGmic.jpg [ 394.99 KiB | Viewed 8272 times ]

Here are some options of this version ("Comic Book" - G'MIC):

Attachment:

apples_k7252-65_gmicOptions.jpg [ 451.63 KiB | Viewed 8272 times ]

Attachment:

apples_k7252-65_gmicOptions2.jpg [ 577.3 KiB | Viewed 8272 times ]

On my PC, with this file, this G'MIC version was faster than the "Comic Book for 2.10" filter.

Have fun!

rich2005 · **Joined:** Mar 04, 2011 **Posts:** 2424

In Windows it is "%APPDATA%\user.gmic"

Now that gmic_gimp_qt stable is now 2.9.8 you might want to look at the changes in the syntax again. As commented on pixlus.
I have been using 2.9.8 for some time now so my bede_cartoon.py script already modified.

Code: Select all

    #pdb.plug_in_gmic_qt(img, layer, 1, 0, '-fx_curves_interactive 7,0,1,7,0,0,'+pointLum+',100,100,-1,0,0,'+pointSat+',100,100,-1,0,0,100,100,-1,0,0,100,100,-1,')
    pdb.plug_in_gmic_qt(img, layer, 1, 0, 'fx_curves_interactive 7,0,1,"7","0,0,'+pointLum+',100,100,-1,0,0,'+pointSat+',100,100,-1,0,0,100,100,-1,0,0,100,100,-1"')

The .gmic file, well I got that going with some nested quotes

Code: Select all

+fx_curves_interactive.  7,0,1,"7","0,0,{'50-$augmLum'},{'50+$augmLum'},100,100,-1,0,0,{'50-$augmSat'},{'50+$augmSat'},100,100,-1,0,0,100,100,-1,0,0,100,100,-1"

....but the simplify variable can throw up an out of range error

beyond my pay-grade.

cli345 · **Posted:** Wed Jul 28, 2021 9:55 am **(#76)**

Thank you very much, rich2005! :tyspin

Indeed, I haven't seen that G'MIC stable version has become "2.9.8" for 11 days!
Now, I've upgraded to 2.9.8 and clicked on "Update Filters" button.

Here is the fixed (for G'MIC 2.9.8 only) version:

Code: Select all

#@gui ____<b>Testing</b>
#@gui <i>cli345</i>
#------------------
#@gui Comic book: comic, comic_preview(0)
#@gui : note = note("<b>Note</b>: Photo to cartoon")
#@gui : sep = separator()
#@gui : note = note(" ")
#@gui : Simplification = choice(0, "none", "light", "light antialias", "strong antialias", "median", "iuwt", "thin brush")
#@gui : sep = separator()
#@gui : note = note("<b>For edges:</b>")
#@gui : Flattening for edge (bilateral) = int(2,0,5)
#@gui : Edge method = choice(0, "Diff. of Gauss.", "Diff. of BoxBlur", "Diff. of Median")
#@gui : Edge desaturation method = choice(1, "Lightness", "MaxRGB", "MinRGB")
#@gui : Line thickness = float(1,0.5,2)
#@gui : Line strength = float(15,0,19)
#@gui : sep = separator()
#@gui : Add colors = bool(1)
#@gui : note = note("<b>For colors:</b>")
#@gui : Luminosity increase = int(10,0,50)
#@gui : Saturation increase = int(20,0,50)
#@gui : Final flattening (bilateral) = int(6,0,10)
#@gui : Lines antialias = int(15,0,100)
#@gui : Colors to black or white = bool(0)
#@gui : sep = separator()
#@gui : url = link("Filter discussed here","http://gimpchat.com/viewtopic.php?f=11&t=19335&p=266517#p266512")

comic :
   simplif=$1
   nbBilatBord=$2
   methBord=$3
   methDesat=$4
   lineThick=$5
   forceTrait=$6
   addColors=$7
   augmLum=$8
   augmSat=$9
   nbBilatFin=$10
   antialias=$11
   bw=$12
   
   if $simplif==2
      fx_smooth_antialias. 100,0,2.5,0,50,50
   elif $simplif==3
      fx_smooth_antialias. 100,0,5,0,50,50
   elif $simplif==4
      fx_smooth_median. 3,255,0,0,50,50
   elif $simplif==5
      jeje_denoise_iuwt. 3,4,2,0
      jeje_denoise_iuwt. 3,4,2,0
   elif $simplif==6
      fx_smooth_anisotropic. 60,0.9,0.64,3.1,1.1,0.8,30,2,0,1,1,0,0,24
   fi
   
   curv="0,0,"{50-$augmLum}","{50+$augmLum}",100,100,-1,0,0,"{50-$augmSat}","{50+$augmSat}",100,100,-1,0,0,100,100,-1,0,0,100,100,-1"
   +fx_curves_interactive.  7,0,1,"7",$curv
   fx_smooth_nlmeans.. 4,4,10,5,0,0,24,0
   fx_smooth_bilateral.. 10,7,$nbBilatBord,0,0
   
   +cut.. 0,255
   reverse[-2,-1]
   if $methBord==0
      blur[-3] {$lineThick}
   elif $methBord==1
      boxfilter[-3] xy,{$lineThick+0.01}
   elif $methBord==2
      median[-3] {($lineThick+0.01)*2}
   fi
   sub[-3,-2]
   
   if $methDesat==0
      fill.. "m = min(R,G,B); M = max(R,G,B); L = 0.5*(m + M); [L, L, L]"
   elif $methDesat==1
      fill.. "M = max(R,G,B); [M, M, M]"
   elif $methDesat==2
      fill.. "M = min(R,G,B); [M, M, M]"
   fi

   cut.. 0,255 n.. 0,255
   negate..
   threshold.. {$forceTrait+80}%
   n.. 0,255
   
   if $simplif>0
      fx_smooth_antialias.. 100,0,2.5,0,50,50
      fx_curves_interactive.. 7,0,1,"7","0,0,69,0,70,100,100,100,-1,0,0,100,0,-1,0,0,100,100,-1,0,0,100,100,-1"
   fi
   
   fx_smooth_antialias.. $antialias,0,1,0,50,50
   
   if $addColors==1
      mul[-2,-1]
      n. 0,255
      fx_smooth_bilateral. 10,7,$nbBilatFin,0,0
      if $bw==1
         fx_curves_interactive 7,0,1,"7","0,0,16,100,100,100,-1,0,0,100,0,-1,0,0,100,100,-1,0,0,100,100,-1"
      fi
   else
      remove[-1]
   fi

comic_preview :
   comic $*

EDIT: Now, you can just type "Ctrl-R" on G'MIC window and the "plug-in" appears in "Filters -> G'MIC-Qt -> Artistic -> Comic Book" (for G'MIC 2.9.8 only).

Here is the fixed (for G'MIC 2.9.8 only) "Simple cartoon" plug-in:

rich2005 · **Joined:** Mar 04, 2011 **Posts:** 2424

The .gmic code is quick and gives a really good result.
The frequent updating of the gmic syntax is understandable - gmic is work-in-progress but frequently results in filters breaking.

(Using a 2.10.22 appimage and a gmic_gimp_qt 2.9.8 plugin that I compile for it.)

cli345 · **Posted:** Fri Jul 30, 2021 9:46 am **(#78)**

Thanks, rich2005!

Here is the fixed (for G'MIC 2.9.8 only) "groove" plug-in:

cli345 · **Posted:** Sun Aug 01, 2021 8:53 am **(#79)**

Thanks to Michael for his video (in German)! :tyspin

cli345 · **Posted:** Sat Aug 07, 2021 3:50 pm **(#80)**

Hello!

If you have Gimp 2.8 + G'MIC 1.7.9, you can install this version of the G'MIC plug-in:
(for G'MIC 1.7.9 only)

Code: Select all

#@gimp ____<b>Artistic</b>
#------------------
#@gimp Comic Book: comicprev, comicprev_preview(0)
#@gimp : note = note("<b>Note</b>: Photo to cartoon")
#@gimp : sep = separator()
#@gimp : note = note(" ")
#@gimp : Simplification = choice(0, "None", "Light", "Light Antialias", "Strong Antialias", "Median", "Iuwt", "Thin Brush")
#@gimp : sep = separator()
#@gimp : note = note("<b>For edges:</b>")
#@gimp : Flattening for Edge (bilateral) = int(2,0,5)
#@gimp : Edge Method = choice(0, "Diff. of Gauss.", "Diff. of BoxBlur", "Diff. of Median")
#@gimp : Edge Desaturation Method = choice(1, "Lightness", "MaxRGB", "MinRGB")
#@gimp : Line Thickness = float(1,0.5,2)
#@gimp : Line Strength = float(15,0,19)
#@gimp : sep = separator()
#@gimp : Add Colors = bool(1)
#@gimp : note = note("<b>For colors:</b>")
#@gimp : Luminosity Increase = int(10,0,50)
#@gimp : Saturation Increase = int(20,0,50)
#@gimp : Final Flattening (bilateral) = int(6,0,10)
#@gimp : Lines Antialias = int(15,0,100)
#@gimp : Colors to Black or White = bool(0)
#@gimp : sep = separator()
#@gimp : Preview type = choice("Full","Forward horizontal","Forward vertical","Backward horizontal","Backward vertical","Duplicate top","Duplicate left","Duplicate bottom","Duplicate right")
#@gimp : sep = separator()
#@gimp : url = link("Filter discussed here","http://gimpchat.com/viewtopic.php?f=11&t=19335&p=266517#p266512")
#@gimp : note = note("<small>Author: <i>Claude Lion</i>.      Latest Update: <i>2021/08/07</i>.</small>")
comicprev :
   -repeat $! -l[$>]

   simplif=$1
   nbBilatBord=$2
   methBord=$3
   methDesat=$4
   lineThick=$5
   forceTrait=$6
   addColors=$7
   augmLum=$8
   augmSat=$9
   nbBilatFin=$10
   antialias=$11
   bw=$12

   -if {$simplif==2}
      -gimp_smooth_antialias. 100,0,2.5,0,50,50
   -elif {$simplif==3}
      -gimp_smooth_antialias. 100,0,5,0,50,50
   -elif {$simplif==4}
      -gimp_smooth_median. 3,255,0,0,50,50
   -elif {$simplif==5}
      -jeje_denoise_iuwt. 3,4,2,0
      -jeje_denoise_iuwt. 3,4,2,0
   -elif {$simplif==6}
      -gimp_smooth_anisotropic. 60,0.9,0.64,3.1,1.1,0.8,30,2,0,1,1,0,0,24
   -endif
   

   curv="0,0,"{50-$augmLum}","{50+$augmLum}",100,100,-1,0,0,"{50-$augmSat}","{50+$augmSat}",100,100,-1,0,0,100,100,-1,0,0,100,100,-1"
   --gimp_curves_interactive.  7,0,1,"7",$curv
   -gimp_smooth_nlmeans.. 4,4,10,5,0,0,24,0
   -gimp_smooth_bilateral.. 10,7,$nbBilatBord,0,0

   --cut.. 0,255
   -reverse[-2,-1]
   -if {$methBord==0}
      -blur[-3] {$lineThick}
   -elif {$methBord==1}
      -boxfilter[-3] xy,{$lineThick+0.01}
   -elif {$methBord==2}
      -median[-3] {($lineThick+0.01)*2}
   -endif
   -sub[-3,-2]

   -if {$methDesat==0}
      -fill.. "m = min(R,G,B); M = max(R,G,B); L = 0.5*(m + M); [L, L, L]"
   -elif {$methDesat==1}
      -fill.. "M = max(R,G,B); [M, M, M]"
   -elif {$methDesat==2}
      -fill.. "M = min(R,G,B); [M, M, M]"
   -endif

   -cut.. 0,255 -n.. 0,255
   -negate..
   -threshold.. {$forceTrait+80}%
   -n.. 0,255

   -if {$simplif>0}
      -gimp_smooth_antialias.. 100,0,2.5,0,50,50
      -gimp_curves_interactive.. 7,0,1,"7","0,0,69,0,70,100,100,100,-1,0,0,100,0,-1,0,0,100,100,-1,0,0,100,100,-1"
   -endif

   -gimp_smooth_antialias.. $antialias,0,1,0,50,50

   -if $addColors
      -mul[-2,-1]
      -n. 0,255
      -gimp_smooth_bilateral. 10,7,$nbBilatFin,0,0
      -if $bw
         -gimp_curves_interactive 7,0,1,"7","0,0,16,100,100,100,-1,0,0,100,0,-1,0,0,100,100,-1,0,0,100,100,-1"
      -endif
   -else
      -remove[-1]
   -endif

   -endl -done

comicprev_preview :
  -gimp_split_preview "-comicprev $*",$-1

Installation:

Copy the above code into a file "~/.gmic" on Linux or a file "%APPDATA%\user.gmic" on Windows.
The "plug-in" appears in "Filters -> G'MIC -> Artistic -> Comic Book".

Have fun!

cli345 · **Posted:** Tue Aug 24, 2021 1:00 pm **(#81)**

Thanks to Miguel Pineau for his video (in French)! :tyspin

Note: For having G'MIC Comic Book filter, you have to:

have the version "2.9.8" of G'MIC
have checked the "internet" case (on G'MIC-Qt window, at the bottom in the middle)
have typed "Ctrl-R" (on G'MIC-Qt window)

Have fun!

cli345 · **Posted:** Thu Nov 25, 2021 9:23 am **(#82)**

Hello,

On some photos, I like when an bump effect is applied after the "Comic Book" effect.

Here is an example:

Attachment:

King_Boletus__Boletus_edulis_bump.jpg [ 58.46 KiB | Viewed 1647 times ]

cli345 · **Posted:** Sun Nov 28, 2021 12:22 pm **(#83)**

I've made it this way:

Open image
Apply "Comic book" filter (in G'Mic)
In G'mic,
- go to "Custom code [Local]",
- paste
  
  Code: Select all
  fx_frame. 0,100,0,100,0,0,255,255,255,255,2,0,0,0,255 fx_custom_transform. "i","if(i<64,0, sqrt((i-64)/(256-64))*256 )","i","i","i","i",0 fx_illuminate_shape2d. 0,0,0,0,0,255,1,1,4,0,0,3,1,1,4,10,75,30,40,40,80,0.2,1,0,0,-2,-2,2,0,0,0 crop. 2,2,{w-4},{h-4}
- click "OK".

Nidhogg · **Posted:** Wed Dec 01, 2021 4:51 am **(#84)**

Thanks! I didn't even know your Comic Book plug-in was added to G'mic, that's good.

PixLab · **Posted:** Wed Dec 01, 2021 12:20 pm **(#85)**

cli345 wrote:

I've made it this way:

Open image
Apply "Comic book" filter (in G'Mic)
In G'mic,
- go to "Custom code [Local]",
- paste
  
  Code: Select all
  fx_frame. 0,100,0,100,0,0,255,255,255,255,2,0,0,0,255 fx_custom_transform. "i","if(i<64,0, sqrt((i-64)/(256-64))*256 )","i","i","i","i",0 fx_illuminate_shape2d. 0,0,0,0,0,255,1,1,4,0,0,3,1,1,4,10,75,30,40,40,80,0.2,1,0,0,-2,-2,2,0,0,0 crop. 2,2,{w-4},{h-4}
- click "OK".

That code is a cool effect, I can see many other uses of this effect as well, thank you :clap

cli345 · **Posted:** Fri Dec 03, 2021 11:30 am **(#86)**

Happy to help!

I intended to add this additional effect and two other ones in the "Comic Book" filter.
I would add a drop-down list titled "Additional Effect" with 4 choices : "None", "Deep Black", "Groove", "Bump".

Here are examples:

Attachment:

Ranunculus_gramineus_blossom_addiEffect.jpg [ 287.62 KiB | Viewed 1467 times ]

Attachment:

Goldfish_photo_2_small_addiEffect.jpg [ 289.38 KiB | Viewed 1467 times ]

Attachment:

377-white-duck-in-greenish-water_addiEffect.jpg [ 240.57 KiB | Viewed 1467 times ]

cli345 · **Posted:** Sat Feb 05, 2022 11:14 am **(#87)**

Hello!

The G'Mic filter "Comic Book" now has new additional effects (Hit "Ctrl-R" on G'Mic window to get them).

Color Effect: Deep Black, Colorful.
Flat Color Effect: Rainbow, Hard Rainbow, Posterize Softly, Super Flat.
Relief Effect: Groove, Bump.

The "Colors to Black or White" checkbox has become a dropdown list: Soft Threshold, Threshold with Soft Antialias, Lines and Black.
The old checked "Colors to Black or White" is equivalent to the new "Colors to Black or White = Soft Threshold" (as in this post of Jappaloe63).
"Lines and Black" is the same effect as in this post.

A "Final Antialias" checkbox is added.

Here are a few examples of "Color Effect" and "Flat Color Effect":

Attachment:

King_Boletus__Boletus_edulis_small_addiEffect_compare2.jpg [ 832.08 KiB | Viewed 1261 times ]

Attachment:

wolf_on_ridge_small_addiEffect_compare2.jpg [ 676.02 KiB | Viewed 1261 times ]

Have fun!

cli345 · **Posted:** Sun Aug 07, 2022 12:22 pm **(#88)**

Thanks to Como Tempera for the video! :tyspin

Note: After the video was made, the syntax of the filter has changed, the new command (default parameters) is now:

Code: Select all

gmic sp -cl_comic 0,2,0,1,1,15,15,1,10,20,6,2,0,0,0,0,0,0,50,50 -display

contrast_ · **Joined:** Oct 31, 2020 **Posts:** 1393

I can easily convert this to GEGL now as I have your original graph.

Code: Select all

#cli345's photo to cartoon filter
id=myStart

noise-reduction
domain-transform n-iterations=5
difference-of-gaussians radius1=1 radius2=0.33
gimp:desaturate mode=value
levels in-low=0.007 in-high=0.009
invert-gamma
rgb-clip

multiply aux=[ ref=myStart saturation scale=1.8 hue-chroma lightness=10 ]
domain-transform 
domain-transform 
domain-transform 
domain-transform 
noise-reduction

It will take a hour or two but I know I make this into a filter. I just need at least one person to request for me to go going.

When I make a thread about the filter I will put in the title "cli345's GEGL Cartoon effect (IN GEGL)"

So, does anyone have interest?

mahvin · **Joined:** Oct 06, 2010 **Posts:** 4045

cli345 wrote:

Thanks to Como Tempera for the video! :tyspin

Note: After the video was made, the syntax of the filter has changed, the new command (default parameters) is now:

Code: Select all

gmic sp -cl_comic 0,2,0,1,1,15,15,1,10,20,6,2,0,0,0,0,0,0,50,50 -display

Good work! Many thanks!

	Similar Topics	Replies
	Turn photo to cartoon manually	6
	Create Wall Photo Strips plugin	4
	Create a Shape Cluster Photo Display plugin	5
	New Fake Paintings (Show of results)	40
	Neon-Cartoon Abstract.	4